定制一个Gradle Plugin --- project-structure

最近在项目中遇到一个不大，但是还蛮烦人的问题，在Maven的约定中，一个标准Java项目的代码结构如下：

project
--src
    --main
        --java
        --resources
    --test
        --java
        --resources

   
当‘gradle idea’构建intelliJ项目文件时，会自动帮忙设置好所有的Source Root，Test Source Root。但是，在我工作的部门中，我们希望可以把测试分为unit，intg2个类别，这样可以更加容易区分测试的目的，同时提供了Build Pipeline分别运行不同类别测试的能力。因此，我们部门内的标准Java项目结构如下：

project
--src
    --main
        --java
        --resources
    --test
        --common
    	    --java
        --unit
    	    --java
    	    --resources
        --intg
    	    --java
    	    --resources

有了这个目录结构之后我们剩下2个问题要解决：
1. 如何区分运行IntegrationTest和Unit Test
2. 如何保证‘gradle idea’以后，无需重新设置Test Source Root。因为gradle不具备识别新的代码结构的能力。

如何写一个Gradle Plugin

语言：
Java，Groovy，Scala都可，推荐用Groovy,毕竟Gradle本质上来说就是一个用Groovy写的DSL，使用Groovy可以更一致一点。

注入方式：
Gradle支持3种形式的定制Plugin注入：

• 1. 直接把Plugin源代码直接写在Build Script里面。
• 2. 把Pluigin源代码写到rootProjectDir/buildSrc/src/main/groovy目录下
• 3. 用一个单独的project来写Plugin源代码，然后以jar依赖的形式注入项目。

个人觉得，都想到要自己写一个Plugin了，那么一定是有多个项目公用这个Plugin了，否则的话，直接把Plugin的代码直接写到脚本里就好了。因此，要定制Plugin，在我看来，一定是需要以一个单独的jar形式注入的。

写project-structure Plugin:
在Gradle中，写一个Plugin非常简单，首先，添加项目依赖，我使用Groovy来写插件，所以添加了localGroovy依赖。

apply plugin: 'groovy'

dependencies {
    compile gradleApi()
    compile localGroovy()
}

然后写Plugin的实现代码，实现代码只需要实现Plugin<Project>接口即可，在我的实现代码中，做了两件事，一是定制了项目的代码结构，二是添加了integrationTest Task，该Task只运行*IntegrationTest.class, 这样可以在Build Pipeline分阶段运行Unit Test和IntegrationTest。

import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.tasks.testing.Test

class ProjectStructurePlugin implements Plugin<Project> {
    @Override
    void apply(Project project) {
        project.logger.info "Configuring Project Structure for $project.name"

        project.configurations {
            integrationTestCompile { extendsFrom testCompile }
            integrationTestRuntime { extendsFrom integrationTestCompile, testRuntime }
        }
        configureSourceSets(project)
        addIntegrationTestTask(project)
    }

    private void addIntegrationTestTask(Project project) {
        Test intgTest = project.getTasks().create("integrationTest", Test.class);
        intgTest.testClassesDir = project.sourceSets.integrationTest.output.classesDir
        intgTest.includes = ["**/*IntegrationTest.class"]
        intgTest.inputs.dir 'src'
        intgTest.outputs.dir project.sourceSets.integrationTest.output.classesDir
        project.check.dependsOn project.integrationTest
        intgTest.dependsOn project.test
    }

    private void configureSourceSets(Project project) {
        project.sourceSets {
            test {
                java {
                    srcDir 'src/test/unit/java'
                    srcDir 'src/test/common/java'
                }
                resources {
                    srcDir 'src/test/unit/resources'
                }
            }

            integrationTest {
                java {
                    srcDir 'src/test/intg/java'
                    srcDir 'src/test/common/java'
                }
                resources {
                    srcDir 'src/test/intg/resources'
                }
                compileClasspath = project.sourceSets.main.output + project.sourceSets.test.output + project.configurations.integrationTestCompile
                runtimeClasspath = output + compileClasspath + project.configurations.integrationTestRuntime
            }
        }
    }
}

接着，在项目的src/main/resources/META-INF/gradle-plugins目录下，创建一个文件：<plugin-name>.properties,在该文件中指定Plugin的实现类：

implementation-class=com.xianlinbox.plugins.ProjectStructurePlugin

在项目中使用该Plugin
首先，需要在build.gradle脚本中引入该Plugin的jar包依赖，可以是以文件的形式，当然个人更推荐的是把jar包发布到Maven库中，以Maven依赖的形式的注入，本例中使用的是本地文件依赖：

buildscript {
    dependencies {
        classpath fileTree(dir: 'libs', include: '*.jar')
    }
}

然后，注入编写的插件，注意，该插件必须和java plugin一起使用，因为其中使用到SourceSets属性是从该插件中引入进来的：

apply plugin: 'java'
apply plugin: 'project-structure'

有了这个插件之后，就可以通过‘gradle test’和‘gradle integrationtTest’区别运行UnitTest和IntrgrationTest了。

最后，解决自动设置Test Source Root的问题，只需要在build.gradle为ideaModule Task增加识别Test Source Root的能力即可：

apply plugin: 'idea'
...
idea {
    module {
        testSourceDirs += file('src/test/intg/java')
        testSourceDirs += file('src/test/intg/resources')
    }
}

当然，我们也可以把它写到Plugin中去，在设置为Project-Structrue之后：

......
 compileClasspath = project.sourceSets.main.output + project.sourceSets.test.output + project.configurations.integrationTestCompile
                runtimeClasspath = output + compileClasspath + project.configurations.integrationTestRuntime
project.idea {
            module {
                testSourceDirs = testSourceDirs + new File('src/test/intg/java') + new File('src/test/intg/resources')
            }
        }